[Seri Tutorial SMS Gateway] Membuat Aplikasi Mengirim dan Menerima SMS dengan Visual Basic 6 dan Lawoo SMS Gateway

Lawoo SMS Gateway dapat dikolaborasikan dengan bahasa pemrograman apapun yang Anda kuasai. Pada tutorial sebelumnya telah disajikan cara membuat script PHP untuk mengirim SMS, maka kali ini akan dibahas pembuatan aplikasi Kirim dan Terima SMS menggunakan Bahasa Pemrograman Visual Basic 6.

Catatan: Saya asumsikan bahwasanya Lawoo SMS Gateway sudah terinstall di Sistem Operasi Windows Anda, dan sudah Anda lakukan konfigurasi seperti yang tercantum di dalam buku manual.

Sebelum masuk ke lingkungan pemrograman Visual Basic 6, ada beberapa langkah yang harus dilakukan terlebih dahulu, yaitu membuat USER DSN menggunakan ODBC. Langkah-langkahnya adalah sebagai berikut:
1. Pada Sistem Operasi Windows, Klik START -> CONTROL PANEL, selanjutnya ketik "ODBC" dibagian SEARCH (pojok kanan atas jendela Control Panel), lebih jelasnya lihat gambar di bawah ini:


2. Masih di jendela Control Panel seperti gambar di atas, klik Set up data sources (ODBC).
3. Selanjutnya akan muncul jendela ODBC Data Source Administrator dan klik saja tombol [Add...] seperti gambar di bawah ini:


4. Selanjutnya akan muncul jendela Create New Data Source, pada daftar yang ada, pilih saja MySQL ODBC 3.51 Driver, kemudian klik Next. Lebih jelasnya perhatikan gambar berikut ini:


5. Selanjutnya akan muncul jendela Connector/ODBC - Add Data Source Name. Pada jendela ini isikan parameter-parameter berikut ini:

---

Data Source Name : LawooVB
Server : localhost
User : root
Password:
Database: lawoo_db

---

Perhatikan gambar di bawah ini agar lebih jelas:

Setelah mengisi dengan parameter diatas, klik tombol TEST, dan pastikan muncul informasi bahwa pembuatan koneksi berhasil:

Klik OK untuk menutup jendela konfigurasi data source.
6. Tahap pembuatan koneksi ke MySQL sudah selesai. Tahap berikutnya adalah mulai membuat program dengan Visual Basic 6. Dan Saya asumsikan bahwa Anda setidaknya sudah memahami dasar-dasar pemrograman Visual Basic 6.
7. Buka Microsoft Visual Basic 6, buat sebuah form kosong.
8. Kemudian Klik Menu PROJECT --> COMPONENTS. Pada daftar komponen, pilih: (a) Microsoft ADO Data Control 6.0, dan (b) Microsoft DataGrid Control 6.0 kemudian klik OK. Lebih jelasnya perhatikan gambar berikut:


9. Selanjutnya desainlah sebuah form seperti pada gambar berikut ini:

Adapun komponen-komponen yang ditambahkan ke dalam form dan properti yang diatur adalah sebagai berikut:

10. Selanjutnya memulai pembuatan kode programnya. Untuk masuk ke editor program, klik menu VIEW-CODE. kemudian ketik baris-baris kode berikut:
Private Sub IsiModem()
    With adoMODEM
        .CommandType = adCmdText
        .RecordSource = "SELECT * FROM modem"
        .Refresh
        If .Recordset.RecordCount > 0 Then
            cboModem.Clear
            .Recordset.MoveFirst
            While Not .Recordset.EOF
                    cboModem.AddItem .Recordset.Fields("IMEI").Value
                    .Recordset.MoveNext
            Wend
        End If
    End With
    If cboModem.ListCount > 0 Then cboModem.ListIndex = 0
End Sub
==========================
Private Sub TampilkanOutbox()
    With adoOUTBOX
        .CommandType = adCmdText
        .RecordSource = "SELECT DESTINATIONNUMBER, MESSAGES, SENDINGDATETIME, PRIORITY, IMEI FROM outbox"
        .Refresh
        lblStatusOutbox.Caption = "Jumlah Antrian SMS: " & .Recordset.RecordCount
    End With
    With dgOUTBOX
        .RowHeight = 600
        Set .DataSource = adoOUTBOX
        .Columns(0).Caption = "No. Tujuan"
        .Columns(1).Caption = "Pesan"
        .Columns(2).Caption = "Tgl. Jam"
        .Columns(3).Caption = "Prioritas"
        .Columns(4).Caption = "IMEI"
        .Columns(0).Width = 1100
        .Columns(1).Width = 3500
        .Columns(2).Width = 800
        .Columns(3).Width = 800
        .Columns(4).Width = 800
        .Columns(0).WrapText = True
        .Columns(1).WrapText = True
        .Columns(2).WrapText = True
        .Columns(3).WrapText = True
        .Columns(4).WrapText = True
    End With
End Sub
==========================
Private Sub TampilkanInbox()
    With adoINBOX
        .CommandType = adCmdText
        .RecordSource = "SELECT NOOA, UD, SCTS_D, SCTS_T FROM inbox ORDER BY ID DESC"
        .Refresh
        lblStatusInbox.Caption = "Jumlah SMS di Inbox: " & .Recordset.RecordCount
    End With
    With dgINBOX
        .RowHeight = 600
        Set .DataSource = adoINBOX
        .Columns(0).Caption = "No. Pengirim"
        .Columns(1).Caption = "Pesan"
        .Columns(2).Caption = "Tgl"
        .Columns(3).Caption = "Jam"
        .Columns(0).Width = 1000
        .Columns(1).Width = 3500
        .Columns(2).Width = 800
        .Columns(3).Width = 800
        .Columns(0).WrapText = True
        .Columns(1).WrapText = True
        .Columns(2).WrapText = True
        .Columns(3).WrapText = True
    End With
End Sub
==========================
Private Sub cmdKirim_Click()
    Dim vIMEI As String
    Dim vNoTujuan As String
    Dim vPesan As String
    Dim vTimeStamp As String
    Dim vPriority As Integer
    vIMEI = cboModem.Text
    vNoTujuan = txtNoTujuan.Text
    vPesan = txtPesan.Text
    vTimeStamp = Format(Now, "yyyy-MM-dd HH:mm")
    vPriority = 5 'Normal
    With adoOUTBOX
        .Recordset.AddNew
        .Recordset.Fields("SENDINGDATETIME").Value = vTimeStamp
        .Recordset.Fields("MESSAGES").Value = vPesan
        .Recordset.Fields("DESTINATIONNUMBER").Value = vNoTujuan
        .Recordset.Fields("PRIORITY").Value = vPriority
        .Recordset.Fields("IMEI").Value = vIMEI
        .Recordset.Update
     End With
     txtNoTujuan.Text = ""
    txtPesan.Text = ""
End Sub
==========================
Private Sub cmdTutup_Click()
    Unload Me
End Sub
==========================
Private Sub Form_Load()
    adoINBOX.ConnectionString = "DSN=LawooVB"
    adoOUTBOX.ConnectionString = "DSN=LawooVB"
    adoMODEM.ConnectionString = "DSN=LawooVB"
    IsiModem
    TampilkanOutbox
    TampilkanInbox
End Sub
==========================
Private Sub Timer1_Timer()
    TampilkanOutbox
    TampilkanInbox
End Sub
==========================
11. Selesai, Simpan form dan project Anda, kemudian Jalankan program dengan menekan tombol F5 atau ikon START.

12. Saatnya mengujicoba mengirim dan menerima SMS dengan Lawoo SMS Gateway. Pastikan Server Lawoo SMS Gateway sudah berjalan agar program yang Anda buat diatas dapat mengirim dan menerima SMS dengan lancar.
13. Selamat berkarya. Untuk source code program pada tutorial ini dapat di download di sini.

Source:  http://smsgateway.web.id/

HOT INFO

Anda ingin mencari refrensi dan contoh program lengkap ? Kami ada. Sekarang Anda bisa mencari SMS Gateway Visual Basic di situs ini : www.panduanSkripsi.net. Koleksi program lengkap di sana, proyek PHP dan MySQL, juga jQuery dan Framework. Bukunya juga ada.